Amanita Design forum

REBOL [
	title: "Machinarium save's tool"
	purpose: "Stores/restores Machinarium's save file (local shared object)"
]

saves: context [
	verbose: true
	
	store: func[
		"Gets Machinarium's save file and stores it in the current dir"
	][
		write/binary %Machinarium.sol read/binary get-machinarium.sol-file
		end-message "Machinarium.sol file found and stored."
	]
	
	restore: func[
		"Gets Machinarium's save file from the current dir and restores it"
	][
		write/binary get-machinarium.sol-file read/binary %Machinarium.sol
		end-message "Machinarium.sol file found and restored."
	]
	
	get-current-dir-path: func[
		"Returns absolute path to current dir without a drive letter"
		/local current-dir
	][
		current-dir: what-dir
		unless exists? current-dir/Machinarium.exe [
			end-message "ERROR: Cannot find Machinarium.exe file!"
		]
		find/tail next current-dir #"/"
	]
	
	get-machinarium.sol-file: func[
		"Returns Machinarium.sol file or quits"
		/local app-dir sol-dirs sol-file
	][
		app-dir:  to-rebol-file get-env "APPDATA"
		sol-dirs: join app-dir %/Macromedia/Flash%20Player/#SharedObjects/
		foreach id read sol-dirs [
			sol-file: rejoin [
				sol-dirs
				id
				%localhost/
				get-current-dir-path
				%Machinarium.exe/Machinarium.sol
			] 
			if exists? sol-file [
				if verbose [
					print join "^/SOL file:^/" to-local-file sol-file
				]
				return sol-file
			]
		]
		end-message "ERROR: machinarium.sol file not found!"
	]

	end-message: func[msg][
		if any [
			verbose
			find msg "ERROR"
		][
			print join "^/" msg
			ask "(Press enter to continue) "
		]
	]
	
	switch/default system/script/args [
		;command line version:
		"store"   [verbose: false store  ]     
		"restore" [verbose: false restore]
	][
		;interactive version:
		forever [
			prin  "^(1B)[J" ;clears screen
			print "== Machinarium's saves (local shared object) ================================="
			print "=============================================================================="
			print "1) store   (Gets Machinarium's save file and stores it in the current dir)"
			print "2) restore (Gets Machinarium's save file from the current dir and restores it)"
			print "3) quit"
			print "------------------------------------------------------------------------------"
			switch ask "What do you want? [1,2,3] " [
				"1" [store]
				"2" [restore]
				"3" [quit]
			]
		]
	]
]